home *** CD-ROM | disk | FTP | other *** search
/ TeX 1995 July / TeX CD-ROM July 1995 (Disc 1)(Walnut Creek)(1995).ISO / systems / mac / oztex / mf.hqx / Metafont / mfinputs / itald.mf < prev    next >
Text File  |  1994-08-19  |  12KB  |  260 lines
  1. % This file contains the ten digits in so-called italic style.
  2. % Character codes \0060 through \0071 are generated.
  3.  
  4. % The characters all have the same italic correction.
  5.  
  6. cmchar "Italic numeral 0";
  7. beginchar("0",9u#,fig_height#,0);
  8. italcorr fig_height#*slant-.5u#;
  9. adjust_fit(0,0);
  10. penpos1(vair,90); penpos3(vair,-90); penpos2(curve,180); penpos4(curve,0);
  11. if not monospace: interim superness:=sqrt(more_super*hein_super); fi
  12. x2r=hround(1.5u-.5curve); x4r=w-x2r; x1=x3=.5w;
  13. y1r=h+o; y3r=-o; y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  14. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  15.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  16. penlabels(1,2,3,4); endchar;
  17.  
  18. cmchar "Italic numeral 1";
  19. beginchar("1",9u#,fig_height#,0);
  20. italcorr fig_height#*slant-.5u#;
  21. adjust_fit(0,0); pickup tiny.nib;
  22. numeric light_stem; light_stem=hround .4[stem',cap_stem'];
  23. pos1(light_stem,0); pos2(light_stem,0);
  24. lft x1l=lft x2l=hround(.5(w+.5u)-.5cap_stem'); top y1=h+apex_o; bot y2=0;
  25. filldraw stroke z1e--z2e;  % stem
  26. dish_serif(2,1,a,1/3,min(2.25u,lft x2l-1.5u),
  27.   b,1/3,min(2.25u,w-1.25u-rt x2r)); % serif
  28. pickup crisp.nib; pos3(slab,-90); pos4(bar,-90);
  29. top y3l=h+apex_o; top y4l=.8h+apex_o;
  30. lft x4=max(1.25u,tiny.lft x1l-2.35u); tiny.rt x1r=lft x3+.25[tiny,hair];
  31. erase fill z3l{x4l-x3l,3(y4l-y3l)}...z4l{left}
  32.  --(x4l,h+apex_o+1)--(x3l,h+apex_o+1)--cycle; % erase excess at top
  33. filldraw stroke z3e{x4e-x3e,3(y4e-y3e)}..{left}z4e;  % point
  34. penlabels(1,2,3,4); endchar;
  35.  
  36. cmchar "Italic numeral 2";
  37. beginchar("2",9u#,fig_height#,0);
  38. italcorr fig_height#*slant-.5u#;
  39. adjust_fit(0,0); pickup fine.nib;
  40. pos1(vair,45); pos2(vair,0); pos3(vair,-90); pos4(hair,-180);
  41. pos5(vair,-270); pos6(curve,-360); pos7(hair,-405); pos8(hair,-360);
  42. x1=x2-.5u; rt x2r=hround(3.5u+.5vair);
  43. x3=.6[x2,x4]; lft x4r=hround(u-.5hair);
  44. x5=x7=.5w-.5u; rt x6r=hround(w-u); lft x8l=hround(1.5u-.5hair);
  45. y1=.5[x_height,h]; y2=1/3[y1,y3]; y4=x_height; bot y3r=vround .78y4;
  46. top y5r=h+o; y6=.5[y5,y7]; y7=.52y4; bot y8=-o;
  47. filldraw stroke if not hefty:z1e{2(x2-x1),y2-y1}...{down}z2e...{left}z3e...fi
  48.  z4e{up}...pulled_arc.e(5,6)
  49.  ...z7e{2(x7-x6),y7-y6}...{down}z8e; % main stroke
  50. pos9(vair,-90); pos10(vstem+curve-stem,-90); pos11(hair,0);
  51. x9=w-x10=2.5u; rt x11r=hround(w-.5u+.5hair);
  52. y9=.25[y10,y7]; bot y10r=-o; y11=.38x_height;
  53. filldraw stroke z8e{up}...z9e{right}..{right}z10e...{up}z11e;  % bar
  54. penlabels(1,2,3,4,5,6,7,8,9,10,11); endchar;
  55.  
  56. cmchar "Italic numeral 3";
  57. beginchar("3",9u#,fig_height#,0);
  58. italcorr fig_height#*slant-.5u#;
  59. adjust_fit(0,0); pickup fine.nib;
  60. pos1(vair,45); pos2(vair,0); pos3(vair,-90); pos4(hair,-180);
  61. pos5(vair,-270); pos6(stem,-360); pos7(bar,-450); pos8(bar,-450);
  62. x1=x2-.5u; rt x2r=hround(3.5u+.5vair); x3=.5[x2,x4]; lft x4r=hround u;
  63. x5=x7=.5w; rt x6r=hround(w-u); x8=x7-u;
  64. y1=.5[x_height,h]; y2=.5[y1,y3]; y7=y8=.52h; bot y3r=vround 1/4[y7,h];
  65. y4=1/3[y3,y5]; top y5r=h+o; y6=.5[y5,y7];
  66. filldraw stroke if not hefty: z1e{2(x2-x1),y2-y1}...{down}z2e...{left}z3e...fi
  67.  z4e{up}...pulled_arc.e(5,6) & pulled_arc.e(6,7)..z8e; % upper arc
  68. pos7'(vair,90); z7'l=z7r;
  69. pos9(curve,0); pos10(vair,-90); pos11(hair,-180); pos12(flare,-180);
  70. rt x9r=hround(w-u); x10=.5w-.5u; lft x11r=hround .75u;
  71. y9=.25h; bot y10r=-o; y11=1/3x_height; bulb(10,11,12);  % bulb
  72. filldraw stroke pulled_arc.e(7',9) & pulled_arc.e(9,10);  % lower arc
  73. penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
  74.  
  75. cmchar "Italic numeral 4";
  76. beginchar("4",9u#,fig_height#,desc_depth#);
  77. italcorr fig_height#*slant-.5u#;
  78. adjust_fit(0,0); pickup fine.nib;
  79. pos1(stem,0); pos6(stem,0); pos7(stem,0);
  80. pos2(bar,-45); pos3(bar,-90); pos4(bar,-90); pos5(bar,-45);
  81. rt x1r=hround(.5w+.5u+.5stem); lft x2l=hround .25u;
  82. x3=2.75u; x4=w-2u; rt x5r=hround(w-.25u);
  83. rt x6r=rt x7r=hround(2/3w+.5stem);
  84. y1+.5stem=h+o; bot y2r=0; bot y3r=vround(.08h-.5bar);
  85. bot y4r=vround-.5bar; bot y5r=vround(.03h-.5bar);
  86. y6+.5stem=bar_height; y7-.5stem=-d;
  87. filldraw circ_stroke z1e{down}...{3(x2-x1),y2-y1}z2e;  % diagonal
  88. filldraw stroke z2e{z1-z2}...z3e{right}..{right}z4e
  89.  ...{x5-x4,2(y5-y4)}z5e;  % bar
  90. filldraw z6l---z7l..z7r---z6r..cycle;  % stem
  91. penlabels(1,2,3,4,5,6,7); endchar;
  92.  
  93. cmchar "Italic numeral 5";
  94. beginchar("5",9u#,fig_height#,0);
  95. italcorr fig_height#*slant-.5u#;
  96. adjust_fit(0,0);
  97. numeric bot_thickness,light_hair;
  98. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  99. light_hair=hround(cap_hair if hefty: -\\2stem_corr fi);
  100. pickup tiny.nib; pos5(vair,180); pos6(vair,90);
  101. bot y5=vround(.53h-vair); top y6r=max(vround .61803h+o,top y6r+y5+eps-y6l);
  102. pos3(light_hair,0); pos4(light_hair,0);
  103. lft x3l=max(1.35u,2.1u-.5light_hair); x3=x4=x5; y4=y5;
  104. top y3=h if not hefty: +\\o fi;
  105. filldraw stroke z3e--z4e;  % thin stem
  106. penpos7(cap_stem-fine,0); penpos8(bot_thickness-fine,-90);
  107. fine.rt x7r=hround(w-.9u); x8=.5[u,x7]; x6=.5[x5,x7];
  108. erase fill z5--bot z5--(x6,bot y5)--z6{left}
  109.  ..tension .9 and 1..{x5-x6,3(y5-y6)}cycle; % erase excess in middle
  110. filldraw stroke z6e{left}..tension .9 and 1..{x5-x6,3(y5-y6)}z5e;  % link
  111. pickup fine.nib; pos6'(vair,90); z6'=z6;
  112. y7=.5[y6,y8]; bot y8r=-o;
  113. filldraw stroke pulled_arc.e(6',7) & pulled_arc.e(7,8);  % bowl
  114. if serifs: pos9(hair,-180); y9=.5y5; lft x9r=hround .9u;
  115.  pos10(flare+1/3(cap_stem-stem),-180); bulb(8,9,10);  % bulb
  116. else: pos9(3/7[bot_thickness,flare],angle(-7u,-h));
  117.  lft x9r=hround(tiny.lft x3l-.75u); bot y9r=vround .15h-o;
  118.  x9l:=good.x x9l; y9l:=good.y y9l;
  119.  filldraw stroke term.e(8,9,left,1,4); fi  % terminal
  120. if hefty: pickup crisp.nib; pos1(slab,90); pos2(hair,0);
  121.  top y1r=h; x1=x4; rt x2r=hround(w-1.5u); y2=y1l-eps;
  122.  arm(1,2,a,0,0);  % arm
  123. else: numeric flag_breadth; flag_breadth=7/8[vair,cap_curve];
  124.  pos1(flag_breadth,90); pos2(flag_breadth,60);
  125.  pos0(vair,90); top y1r=tiny.top y3; top y2r=vround .95h+o; y0r=y1r;
  126.  lft x1=tiny.lft x3l; x2r=.5[x1,x0]; rt x0=hround(w-1.6u);
  127.  erase fill top z1r--z1r...{right}z2r
  128.   --(x2r,top y1r)--cycle; % erase excess at top
  129.  filldraw stroke z1e...{right}z2e...z0e; fi  % flag
  130. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  131.  
  132. cmchar "Italic numeral 6";
  133. beginchar("6",9u#,fig_height#,0);
  134. italcorr fig_height#*slant-.5u#;
  135. adjust_fit(0,0);
  136. numeric top_thickness,bot_thickness,side_thickness,pull;
  137. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  138. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  139. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  140. pull=min(.25,1.5superpull);
  141. pickup fine.nib; pos2(top_thickness,-270);
  142. pos3(side_thickness,-180); pos4(bot_thickness,-90);
  143. pos5(side_thickness,0); pos6(vair,90);
  144. lft x3r=w-rt x5r=hround max(.75u,1.5u-.5side_thickness);
  145. x4=x6-.1u=x2-u=.5w;
  146. top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
  147. y5=.5[y4,y6]; top y6=vround 5/8h+o;
  148. path p; p=pulled_super_arc.l(3,4)(pull);
  149. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  150. pos7(thin_join,180); z7l=point t of p;
  151. (x,y6r)=whatever[z7l,z6l]; x6r:=min(x,.5[x5r,x6]);
  152. filldraw stroke pulled_super_arc.e(2,3)(pull)
  153.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  154.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  155.  & z6e{left}...{direction t of p}z7e;  % arc and bowl
  156. if serifs: pos1(hair,-360); pos0(flare,-360);
  157.  rt x0r=max(rt x2+eps,hround(w-1.2u));
  158.  y0=vround min(.9h-.5flare,.85h+.5flare)+o;
  159.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  160. else: pos1(vround .1[top_thickness,flare],90);
  161.  top y1r=vround .97h+o; rt x1=hround(x5-.5);
  162.  filldraw stroke term.e(2,1,right,.9,4); fi  % terminal
  163. penlabels(0,1,2,3,4,5,6,7); endchar;
  164.  
  165. cmchar "Italic numeral 7";
  166. beginchar("7",9u#,fig_height#,desc_depth#);
  167. italcorr fig_height#*slant-.5u#;
  168. adjust_fit(0,0); pickup fine.nib;
  169. numeric fat_curve; fat_curve=1.4[stem,curve];
  170. pos1(hair,0); pos2(hair,0); pos3(vstem+curve-stem,-90);
  171. pos4(vair,-90); pos5(hair,0); pos6(fat_curve,0);
  172. top y1=h+o; y2=x_height; y3l=y5=y1;
  173. bot y4r=vround(.5[y2,h]-.5vair); y6-.5fat_curve=-o;
  174. lft x2l=hround(.5u-.5hair); x3=.5w-.5u; x4=2/3w;
  175. rt x5r=hround(w-.75u+.5hair); rt x6r=hround(.5w+u+.5fat_curve);
  176. z1=z2+whatever*(z5-z6); filldraw stroke z1e--z2e;  % serif
  177. filldraw stroke z2e{z1-z2}...z3e{right}..{right}z4e
  178.  ...{2(x5-x6),y5-y6}z5e;  % bar
  179. filldraw circ_stroke z6e{up}...{2(x5-x6),y5-y6}z5e;  % diagonal
  180. penlabels(1,2,3,4,5,6); endchar;
  181.  
  182. cmchar "Italic numeral 8";
  183. beginchar("8",9u#,fig_height#,0);
  184. italcorr fig_height#*slant-.5u#;
  185. adjust_fit(0,0);
  186. numeric top_thickness,mid_thickness,bot_thickness,upper_side,lower_side,theta;
  187. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  188. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  189. x0=.5w; y0=.54h;
  190. if hefty: mid_thickness=vround 2/3vair; upper_side=hround(stem-3stem_corr);
  191.  lower_side=hround min(.5[curve,cap_curve]-stem_corr,upper_side+.25u);
  192.  penpos1(top_thickness,90); penpos2(upper_side,180);
  193.  penpos3(mid_thickness,270); penpos8(upper_side,360);
  194.  penpos4(mid_thickness,90); penpos7(lower_side,180);
  195.  penpos6(bot_thickness,270); penpos5(lower_side,360);
  196.  penpos0(vair,90); z3l=z0r; z4l=z0l;
  197.  x1=x6=.5w; x2r=w-x8r=hround u; x7r=w-x5r=hround .75u;
  198.  top y1r=h+o; bot y6r=-o; y2=y8=.5[y1l,y3l]; y7=y5=.5[y4l,y6l];
  199.  filldraw stroke pulled_arc.e(1,2)
  200.   & pulled_arc.e(2,3);  % left half of upper bowl
  201.  filldraw stroke pulled_arc.e(4,5)
  202.   & pulled_arc.e(5,6);  % right half of lower bowl
  203.  filldraw stroke pulled_arc.e(6,7)
  204.   & pulled_arc.e(7,4);  % left half of lower bowl
  205.  filldraw stroke pulled_arc.e(3,8)
  206.   & pulled_arc.e(8,1);  % right half of upper bowl
  207. else: pickup fine.nib; theta=90-angle(18u,h); slope:=-h/18u;
  208.  upper_side=max(fine.breadth,hround(.5[hair,stem]-stem_corr));
  209.  lower_side=hround(.5[hair,stem]+stem_corr);
  210.  if lower_side>1.2upper_side: upper_side:=lower_side; fi
  211.  pos1(top_thickness,-90); pos6(bot_thickness,-90);
  212.  x1=x6=.5w; top y1l=h+o; bot y6r=-o; pos0(cap_stem,theta);
  213.  lft x2l=w-rt x8l=hround 1.25u; lft x7r=w-rt x5r=hround .75u;
  214.  x2r-x2l=upper_side-fine; x5r-x5l=lower_side-fine;
  215.  ellipse_set(1l,2l,3l,0l); ellipse_set(1r,2r,3r,0r);
  216.  ellipse_set(6l,5l,4l,0l); ellipse_set(6r,5r,4r,0r);
  217.  numeric tau; tau=max(.8,.20710678/(superness-.5));
  218.  filldraw stroke z1e{left}..tension atleast tau..z2e{down}
  219.   ..z3e---z4e..z5e{down}..tension atleast tau..z6e{left};  % S stroke
  220.  pos7(lower_side,180); pos8(upper_side,180);
  221.  y7=.5[y5l,y5r]; y8=.5[y2l,y2r]; pos9(vair,90); z9=z0;
  222.  filldraw stroke z1e{right}..tension atleast tau..z8e{down}
  223.   ..tension atleast tau and atleast 1..{-18u,-.618h}z9e; % upper right stroke
  224.  filldraw stroke z6e{left}..tension atleast tau..z7e{up}
  225.   ..tension atleast tau and atleast 1..{18u,.5h}z9e; fi % lower left stroke
  226. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  227.  
  228. cmchar "Italic numeral 9";
  229. beginchar("9",9u#,fig_height#,0);
  230. italcorr fig_height#*slant-.5u#;
  231. adjust_fit(0,0);
  232. numeric top_thickness,bot_thickness,side_thickness,pull;
  233. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  234. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  235. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  236. pull=min(.25,1.5superpull);
  237. pickup fine.nib; pos2(bot_thickness,-90);
  238. pos3(side_thickness,0); pos4(top_thickness,90);
  239. pos5(side_thickness,180); pos6(vair,270);
  240. w-rt x3r=lft x5r=hround max(.75u,1.5u-.5side_thickness);
  241. x4-.1u=x6+.1u=x2+.75u=.5w;
  242. bot y2r=-o; y3=.5[y2,y4]; top y4r=h+o;
  243. y5=.5[y4,y6]; bot y6=vround 3/8h-o;
  244. path p; p=pulled_super_arc.l(3,4)(pull);
  245. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  246. pos7(thin_join,360); z7l=point t of p;
  247. (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
  248. filldraw stroke pulled_super_arc.e(2,3)(pull)
  249.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  250.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  251.  & z6e{right}...{direction t of p}z7e;  % arc and bowl
  252. if serifs: pos1(hair,-180); pos0(flare,-180);
  253.  lft x0r=min(lft x2-eps,hround 1.2u);
  254.  y0=vround max(.1h+.5flare,.15h-.5flare)-o;
  255.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  256. else: pos1(.1[bot_thickness,flare],-120);
  257.  bot y1r=vround .07h-o; lft x1r=hround 1.3u;
  258.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal
  259. penlabels(0,1,2,3,4,5,6,7); endchar;
  260.